前面幾篇文章里談到了Erlang的gen_tcp網(wǎng)絡(luò)編程和Erlang/OPT的gen_server模塊，現(xiàn)在讓我們將它們兩者綁定在一起

大多數(shù)人認為“服務(wù)器”意味著網(wǎng)絡(luò)服務(wù)器，但Erlang使用這個術(shù)語時表達的是更抽象的意義
gen_serer在Erlang里是基于它的消息傳遞協(xié)議來操作的服務(wù)器，我們可以在此基礎(chǔ)上嫁接一個TCP服務(wù)器，但這需要一些工作

網(wǎng)絡(luò)服務(wù)器的結(jié)構(gòu)
大部分網(wǎng)絡(luò)服務(wù)器有相似的架構(gòu)
首先它們創(chuàng)建一個監(jiān)聽socket來監(jiān)聽接收的連接
然后它們進入一個接收狀態(tài)，在這里一直循環(huán)接收新的連接，直到結(jié)束（結(jié)束表示連接已經(jīng)到達并開始真正的client/server工作）

先看看前面網(wǎng)絡(luò)編程里的echo server的例子：

-module(echo).
-author('Jesse E.I. Farmer <jesse@20bits.com>').
-export([listen/1]).

-define(TCP_OPTIONS, [binary, {packet, 0}, {active, false}, {reuseaddr, true}]).

% Call echo:listen(Port) to start the service.
listen(Port) ->
    {ok, LSocket} = gen_tcp:listen(Port, ?TCP_OPTIONS),
    accept(LSocket).

% Wait for incoming connections and spawn the echo loop when we get one.
accept(LSocket) ->
    {ok, Socket} = gen_tcp:accept(LSocket),
    spawn(fun() -> loop(Socket) end),
    accept(LSocket).

% Echo back whatever data we receive on Socket.
loop(Socket) ->
    case gen_tcp:recv(Socket, 0) of
        {ok, Data} ->
            gen_tcp:send(Socket, Data),
            loop(Socket);
        {error, closed} ->
            ok
    end.

你可以看到，listen會創(chuàng)建一個監(jiān)聽socket并馬上調(diào)用accept
accept會等待進來的連接，創(chuàng)建一個新的worker（loop）來處理真正的工作，然后等待下一個連接

在這部分代碼里，父進程擁有l(wèi)isten socket和accept loop兩者
后面我們會看到，如果我們集成accept/listen loop和gen_server的話這樣做并不好

抽象網(wǎng)絡(luò)服務(wù)器
網(wǎng)絡(luò)服務(wù)器有兩部分：連接處理和業(yè)務(wù)邏輯
上面講到，連接處理對每個網(wǎng)絡(luò)服務(wù)器都是幾乎一樣的
理想狀態(tài)下我們可以這樣做：

-module(my_server).
start(Port) ->
  connection_handler:start(my_server, Port, businees_logic).

business_logic(Socket) ->
  % Read data from the network socket and do our thang!

讓我們繼續(xù)完成它

實現(xiàn)一個通用網(wǎng)絡(luò)服務(wù)器
使用gen_server來實現(xiàn)一個網(wǎng)絡(luò)服務(wù)器的問題是，gen_tcp:accept調(diào)用是堵塞的
如果我們在服務(wù)器的初始化例程里調(diào)用它，那么整個gen_server機制都會堵塞，直到客戶端建立連接

有兩種方式來繞過這個問題
一種方式為使用低級連接機制來支持非堵塞（或異步）accept
有許多方法來支持這樣做，最值得注意的是gen_tcp:controlling_process，它幫你管理當(dāng)客戶端建立連接時誰接受了什么消息

我認為另一種比較簡單而更優(yōu)雅的方式是，一個單獨的進程來監(jiān)聽socket
該進程做兩件事：監(jiān)聽“接收連接”消息以及分配新的接收器
當(dāng)它接收一條新的“接收連接”的消息時，就知道該分配新的接收器了

接收器可以任意調(diào)用堵塞的gen_tcp:accept，因為它允許在自己的進程里
當(dāng)它接受一個連接后，它發(fā)出一條異步消息傳回給父進程，并且立即調(diào)用業(yè)務(wù)邏輯方法

這里是代碼，我加了一些注釋，希望可讀性還可以：

-module(socket_server).
-author('Jesse E.I. Farmer <jesse@20bits.com>').
-behavior(gen_server).

-export([init/1, code_change/3, handle_call/3, handle_cast/2, handle_info/2, terminate/2]).
-export([accept_loop/1]).
-export([start/3]).

-define(TCP_OPTIONS, [binary, {packet, 0}, {active, false}, {reuseaddr, true}]).

-record(server_state, {
        port,
        loop,
        ip=any,
        lsocket=null}).

start(Name, Port, Loop) ->
    State = #server_state{port = Port, loop = Loop},
    gen_server:start_link({local, Name}, ?MODULE, State, []).

init(State = #server_state{port=Port}) ->
    case gen_tcp:listen(Port, ?TCP_OPTIONS) of
        {ok, LSocket} ->
            NewState = State#server_state{lsocket = LSocket},
            {ok, accept(NewState)};
        {error, Reason} ->
            {stop, Reason}
    end.

handle_cast({accepted, _Pid}, State=#server_state{}) ->
    {noreply, accept(State)}.

accept_loop({Server, LSocket, {M, F}}) ->
    {ok, Socket} = gen_tcp:accept(LSocket),
    % Let the server spawn a new process and replace this loop
    % with the echo loop, to avoid blocking
    gen_server:cast(Server, {accepted, self()}),
    M:F(Socket).
   
% To be more robust we should be using spawn_link and trapping exits
accept(State = #server_state{lsocket=LSocket, loop = Loop}) ->
    proc_lib:spawn(?MODULE, accept_loop, [{self(), LSocket, Loop}]),
    State.

% These are just here to suppress warnings.
handle_call(_Msg, _Caller, State) -> {noreply, State}.
handle_info(_Msg, Library) -> {noreply, Library}.
terminate(_Reason, _Library) -> ok.
code_change(_OldVersion, Library, _Extra) -> {ok, Library}.

我們使用gen_server:cast來傳遞異步消息給監(jiān)聽進程，當(dāng)監(jiān)聽進程接受accepted消息后，它分配一個新的接收器

目前，這個服務(wù)器不是很健壯，因為如果無論什么原因活動的接收器失敗以后，服務(wù)器會停止接收新的連接
為了讓它變得更像OTP，我們因該捕獲異常退出并且在連接失敗時分配新的接收器

一個通用的echo服務(wù)器
echo服務(wù)器是最簡單的服務(wù)器，讓我們使用我們新的抽象socket服務(wù)器來寫它:

-module(echo_server).
-author('Jesse E.I. Farmer <jesse@20bits.com>').

-export([start/0, loop/1]).

% echo_server specific code
start() ->
    socket_server:start(?MODULE, 7000, {?MODULE, loop}).
loop(Socket) ->
    case gen_tcp:recv(Socket, 0) of
        {ok, Data} ->
            gen_tcp:send(Socket, Data),
            loop(Socket);
        {error, closed} ->
            ok
    end.

你可以看到，服務(wù)器只含有自己的業(yè)務(wù)邏輯
連接處理被封裝到socket_server里面
而這里的loop方法也和最初的echo服務(wù)器一樣

希望你可以從中學(xué)到點什么，我覺得我開始理解Erlang了

歡迎回復(fù)，特別關(guān)于是如何改進我的代碼，cheers！
安徽新華電腦學(xué)校專業(yè)職業(yè)規(guī)劃師為你提供更多幫助【在線咨詢】